"ROGUE SUB" An adaption of Hurkle.

Discuss software for the Apple 1/replica 1

"ROGUE SUB" An adaption of Hurkle.

Postby PaulB » Jul Tue 08, 2014 5:39 am

A ever-so slightly more interesting spin on Hurkle, Hope you like it :)

E000R. to enter Basic.
E2B3R and RETURN, to start


E000R
1 PRINT ""
2 REM BY, PAUL BAXTER.
3 REM 4 JULY 2014
9 TAB (10): PRINT "**** **** **** * * ****"
10 TAB (10): PRINT "* * * * * * * * "
11 TAB (10): PRINT "**** * * * * * * "
12 TAB (10): PRINT "** * * **** * * ****"
13 TAB (10): PRINT "* * * * * * * * * "
14 TAB (10): PRINT "* * **** **** **** ****"
15 PRINT ""
17 TAB (16): PRINT "**** * * *** "
18 TAB (16): PRINT "* * * * * "
19 TAB (16): PRINT "**** * * * * "
20 TAB (16): PRINT " * * * ****"
21 TAB (16): PRINT " * * * * *"
22 TAB (16): PRINT "**** **** ****"
23 PRINT ""
24 PRINT ""
25 INPUT "DO YOU WANT TO PLAY A GAME (Y OR N)",A$
26 IF A$="Y" THEN 30
27 IF A$="N" THEN 1000
30 PRINT : PRINT : PRINT
110 N=5
120 G=10
210 PRINT
213 PRINT "A ROGUE SOVIET SUBMARINE HAS TAKEN UP POSITION WITHIN YOUR PATROL AREA."
215 PRINT "THE DERANGED SUB CAPTAIN PLANS TO LAUNCH HIS MISSILES AT WASHINGTON DC."
216 PRINT "STARTING WW3 AND, THE END OF THE WORLD!"
217 PRINT ""
223 PRINT "THE USSR DENY THEY HAVE AN AWOL SUB, WE KNOW IT IS THERE. FIND IT & *KILL IT*."
226 PRINT " YOUR PATROL AREA IS REFERENCED ON A ";G;" BY ";G;" GRID."
235 PRINT "THE GRID IS DESIGNATED BY A PAIR OF"
240 PRINT "WHOLE NUMBERS SEPARATED BY A COMMA. THE"
245 PRINT "1ST NUMBER IS HORIZONTAL POSITION"
246 PRINT "AND THE 2ND NUMBER IS VERTICAL"
247 PRINT "YOUR LOCATION ON THE GRID IS, 00.00 IN THE SOUTHWEST CORNER."
250 PRINT "YOU ONLY HAVE 5 ANTI SUBMARINE MISSILES, YOU MUST FIND THE SUBS GRID POINT AND DESTROY IT!"
251 PRINT ""
252 PRINT "SONAR,, CONTACT N/EAST OF YOU."
280 PRINT
281 INPUT "HIT RETURN TO BEGIN",B$
282 IF B$="" THEN 285
285 A= RND (G)
286 B= RND (G)
310 FOR K=1 TO N
320 PRINT "ENTER COORDINATES TO FIRE MISSILE #";K;
330 INPUT X,Y
340 IF ABS (X-A)+ ABS (Y-B)=0 THEN 500
350 REM PRINT INFO
360 GOSUB 610
370 PRINT
380 NEXT K
410 PRINT
420 PRINT "";N;"TH & LAST MISSILE , SUBMARINE HAS LAUNCHED MISSILES, WE ARE ALL DOOMED. THE SUB WAS AT ";A;",";B
440 PRINT
450 PRINT "LET'S PLAY AGAIN."
460 PRINT
470 GOTO 9
500 REM
510 PRINT
520 PRINT "A HIT WITH MISSILE NUMBER ";K;" YOU SAVED THE WORLD!"
540 GOTO 440
610 PRINT "MISSED!, SONAR CONTACT--";
620 IF Y=B THEN 670
630 IF Y<B THEN 660
640 PRINT "SOUTH";
650 GOTO 670
660 PRINT "NORTH";
670 IF X=A THEN 720
680 IF X<A THEN 710
690 PRINT "WEST";
700 GOTO 720
710 PRINT "EAST";
720 PRINT
730 RETURN
999 END
1000 PRINT "THAT IS A SHAME..GOODBYE!"

1001 END

E2B3R
RUN
PaulB
 
Posts: 17
Joined: Jul Sat 30, 2011 10:56 am

Re: "ROGUE SUB" An adaption of Hurkle.

Postby nama » Oct Thu 30, 2014 10:03 pm

I'll try to add this to 'Ultimate Apple 1 Software collection' when I have time.
Thanks
nama
 
Posts: 20
Joined: Aug Thu 30, 2007 8:48 am

Re: "ROGUE SUB" An adaption of Hurkle.

Postby PaulB » Nov Sat 15, 2014 6:36 am

Great one,
Thanks :D
PaulB
 
Posts: 17
Joined: Jul Sat 30, 2011 10:56 am


Return to Software

Who is online

Users browsing this forum: No registered users and 1 guest

cron